DEV Community: Eduardo Ramírez

Serie de números primos - PSeInt

Eduardo Ramírez — Mon, 29 Apr 2019 01:02:14 +0000

Quizás te interese leer: Determinar si un número es primo - PSeInt

Para comprender el siguiente pseudo-código:

Algoritmo SerieNumerosPrimos

    // Verificaremos uno a uno la serie de números naturales hasta el numeroTope.
    Definir numeroNatural Como Entero;

    // Dividiremos el numeroNatural entre todos los números anteriores a él.
    Definir numeroPredecedor Como Entero;

    // Hasta que número desea el usuario que se obtenga la serie de números primos.
    Definir numeroTope Como Entero;

    // La cantidad de números que al dividir entre el numeroNatural,
    // nos dan una división exacta.
    Definir divisionResiduoCero Como Entero;

    Escribir "Mostrar en pantalla la serie de números primos.";
    Escribir "Teclea el número tope de la serie: ";
    Leer numeroTope;

    Para numeroNatural = 1 Hasta numeroTope Con Paso 1 Hacer

        divisionResiduoCero = 0;

        Para numeroPredecesor = 1 Hasta numeroNatural Con Paso 1 Hacer

            Si(numeroNatural % numeroPredecesor == 0) Entonces
                divisionResiduoCero = divisionResiduoCero + 1;
            FinSi

        FinPara

        Si(divisionResiduoCero == 2) Entonces
            Escribir Sin Saltar, numeroNatural, " ";
        FinSi

    FinPara

FinAlgoritmo

Determinar si un número es primo - PSeInt

Eduardo Ramírez — Sun, 28 Apr 2019 21:11:35 +0000

Tomaremos un número ingresado por el usuario, lo dividiremos por el mismo y todos los números naturales anteriores a él.

Cada vez que la división nos de como resultado un residuo de cero registraremos ese evento en una variable. En el caso de que el número de eventos sea exactamente dos; entonces se trata de un número primo.

Algoritmo DeterminarNumerosPrimos
    Definir numeroIngresado, iteracion, divisionResiduoCero Como Entero;

    Escribir "Determinar si un número ingresado, es un número primo.";
    Escribir "Teclea un número entero: ";
    Leer numeroIngresado;

    // Comenzaremos dividiendo el número ingresado entre 1.
    iteracion = 1;

    // Número de ocasiones en las que la división dio como resultado un residuo de cero.
    divisionResiduoCero = 0;

    Mientras iteracion <= numeroIngresado Hacer

        Si(numeroIngresado % iteracion == 0) Entonces
            divisionResiduoCero = divisionResiduoCero + 1;
        FinSi

        iteracion = iteracion + 1;

    FinMientras

    Si(divisionResiduoCero == 2) Entonces
        Escribir "El número que ingresaste es un número primo.";
    SiNo
        Escribir "El número que ingresaste NO es un número primo.";
    FinSi   

FinAlgoritmo