DEV Community: Dutra

SAS Function setDateByNumberBDays

Dutra — Thu, 18 May 2023 23:56:54 +0000

This function defines a new date by calculating it, starting from the informed one plus the number of working days provided as parameters. When using negative days, it returns previous dates.


proc fcmp outlib=work.sas_functions.dateFunctions;

    /*
    =================== 
     * FUNCTION:setDateByNumberBDays
     * AUTHOR: Dutra - dutra@relevants.org
     * DESCRIPTION: Defines a new date by calculating the 
     number of working days provided as a parameter. 
     When using negative days it returns previous dates.
    ===================
    */
    function setDateByNumberBDays(date, numberDays);

        numberBDays = 0;

        do while (numberBDays < abs(numberDays));
            if numberDays > 0 then
                date = date + 1;
            else
                date = date - 1;

            if isBusinessDay(date) then
                numberBDays = numberBDays + 1;
        end;

        return(date);
    endsub;



quit;

SAS Function isBrHolidayworkingDaysBetweenDates

Dutra — Thu, 18 May 2023 23:31:02 +0000

The function returns the number of working days between two given dates.

proc fcmp outlib=work.sas_functions.dateFunctions;

    /*
    =================== 
     * FUNCTION:workingDaysBetweenDates
     * AUTHOR: Dutra - dutra@relevants.org
     * DESCRIPTION: Returns the number of working days 
     between two given dates
    ===================
    */
    function workingDaysBetweenDates(startDate, endDate);
        numberDays = 0;
        addData = startDate;

        if startDate <= endDate then;
        do while (addData <= endDate);
            if isBusinessDay(addData) <> 0 then
                numberDays = numberDays + 1;
            addData = intnx('day',addData,1);
        end;

        return(numberDays);
    endsub;

quit;

SAS Functions extras for previous or next dates

Dutra — Thu, 18 May 2023 23:20:41 +0000

As auxiliary functions of isBusinessDay, previousBusinessDayand nextBusinessDay, the functions ifNonBDayPreviousBDay and ifNonBDayNextBDay test whether the informed date is a business day, if not, it returns the previous or subsequent business day date, respectively to each function.

proc fcmp outlib=work.sas_functions.dateFunctions;

    /*
    =================== 
     * FUNCTION:ifNonBDayPreviousBDay
     * AUTHOR: Dutra - dutra@relevants.org
     * DESCRIPTION: Checks if the given date is a working day, 
     otherwise returns the previous working day date
    ===================
    */
    function ifNonBDayPreviousBDay(date);
        if isBusinessDay(date) = 0 then
            return(previousBusinessDay(date));
        else return(date);
    endsub;

    /*
    =================== 
     * FUNCTION:ifNonBDayNextBDay
     * AUTHOR: Dutra - dutra@relevants.org
     * DESCRIPTION: Checks if the given date is a working day, 
     otherwise returns the next working day date
    ===================
    */

    function ifNonBDayNextBDay(date);
        if isBusinessDay(date) = 0 then
            return(nextBusinessDay(date));
        else return(date);
    endsub;

quit;

SAS Functions previous and next BusinessDay

Dutra — Thu, 18 May 2023 22:52:57 +0000

The functions with the aid of the previous functions of isBusinessDay and isBrHoliday return the previous or next useful date of an initial date informed in the parameter.

proc fcmp outlib=work.sas_functions.dateFunctions;

    /*
    =================== 
     * FUNCTION:previousBusinessDay
     * AUTHOR: Dutra - dutra@relevants.org
     * DESCRIPTION: Returns the previous working day of a 
       given date
    ===================
    */
    function previousBusinessDay(date);
        previousDay = intnx('day',date,-1);

        do while (isBusinessDay(previousDay) = 0);
            previousDay = intnx('day', previousDay, -1);
        end;

        return(previousDay);
    endsub;

    /*
    =================== 
     * FUNCTION:nextBusinessDay
     * AUTHOR: Dutra - dutra@relevants.org
     * DESCRIPTION: Returns the next working day of a given date
    ===================
    */

    function nextBusinessDay(date);
        nextDay = intnx('day',date,1);

        do while (isBusinessDay(nextDay) = 0);
            nextDay = intnx('day', nextDay, 1);
        end;

        return(nextDay);
    endsub;


quit;

options cmplib=work.sas_functions;

SAS Function isBusinessDay

Dutra — Thu, 18 May 2023 00:29:45 +0000

This is an auxiliary function to isBrHoliday, demonstrated in the previous post, to validate whether a date is a business day, disregarding weekends and holidays. the code can be added along with the previous block inside proc fcmp.

proc fcmp outlib=work.sas_functions.dateFunctions;

    /*
    =================== 
     * FUNCTION:isBusinessDay
     * AUTHOR: Dutra - dutra@relevants.org
     * DESCRIPTION: Tests a date to validate if it is a 
Brazilian national holiday or non-business day, returning 0 or 1.
    ===================
    */
    function isBusinessDay(date);

        if weekday(date) in (1, 7) or isBrHoliday(date) = 1 then
            return(0);
        else return(1);

    endsub;


quit;

options cmplib=work.sas_functions;

SAS Function isBrHoliday

Dutra — Wed, 17 May 2023 23:55:42 +0000

A useful function to test if a date is a Brazilian national holiday. With the necessary adaptations, it can be used for other countries, applying their respective holidays. The function uses proc fcmp to work with executions in a different way than the construction of macros, for this purpose the created functions are stored in a specific library in the outlib parameter.

proc fcmp outlib=work.sas_functions.dateFunctions;

    /*
    =================== 
     * FUNCTION:isBrHoliday
     * AUTHOR: Dutra - dutra@relevants.org
     * DESCRIPTION: Tests a date to validate if it is a 
Brazilian national holiday, returning 0 or 1.
    ===================
    */
    function isBrHoliday(date);
        year                = year(date);
        anonovo             = mdy(01,01,year);
        tiradentes          = mdy(04,21,year);
        diaTrabalho         = mdy(05,01,year);
        independencia       = mdy(09,07,year);
        nsraAparecida       = mdy(10,12,year);
        finados             = mdy(11,02,year);
        republica           = mdy(11,15,year);
        natal               = mdy(12,25,year);
        pascoa              = holiday('easter', year);
        segCarnaval         = pascoa - 48;
        terCarnaval         = pascoa - 47;
        sextaPaixao         = pascoa - 2;
        corpusChristi       = pascoa + 60;

        if date in (anonovo, segCarnaval, terCarnaval,
 sextaPaixao, pascoa, corpusChristi, tiradentes, diaTrabalho,
 independencia, nsraAparecida, finados, republica, natal
               ) then
            return(1);
        else 
            return(0);
    endsub;

quit;

options cmplib=work.sas_functions;

To use the function just call passing the date parameter. As in the following example:

 /*
Function test, defining the date and passing it as a parameter of
the isHoliday function
*/
%let date=%sysfunc(mdy(12,25,2023));

%let isHoliday=%sysfunc(isBrHoliday(&date.));

%put Date=&date. - isHoliday=&isHoliday.;

I hope it can help with your projects. I will also make new posts available about other functions that I use to handle dates.