store89

task(dependsOn: [prepareLibDir, classes], task_name, type: JavaExec) {
    systemProperty "org.gradle.scan.acceptTerm", "true"
    logger.info 'Task: ' + task_name + ' started execution'

    doFirst {
        setTmpDir()
        buildFileSystem("$curInst.temp")
        jvmArgs += prepareJvmArgs()

        def ddsPath = "${System.properties['java.io.tmpdir']}/$curInst.temp/dds"

        def quantumJarFile = sourceSets.main.runtimeClasspath.filter {
            it.toPath().getFileName().toString().endsWith('.jar') && it.toPath().getFileName().toString().contains("quantum")
        }

        // 1. Construct the FULL classpath
        def fullClasspathFiles = files(instanceClasspath) + quantumJarFile + (sourceSets.main.runtimeClasspath + files(ddsPath) - quantumJarFile)
        def fullClasspathString = fullClasspathFiles.asPath

        // 2. Set the CLASSPATH environment variable
        // Windows allows ~32k characters here, vs ~8k on the command line
        environment "CLASSPATH", fullClasspathString

        // 3. Clear the task's classpath property
        // When 'classpath' is empty, the JVM falls back to the CLASSPATH env var
        classpath = files() 

        if (instance_options.isDevLocal?.toString()?.toBoolean()) {
            setupDevConfig()
        }
    }

    main = 'com.citigroup.get.quantum.server.Server' 

    args 'file:///' + file("src/main/config/quantum/$curInst.asset/$curInst.region${curInst.country ? "/$curInst.country" : ""}/$curInst.env"),
         "$curInst.instance",
         'dummy'

    workingDir file('src/main/config')
    standardInput = System.in
}