DEV Community

loading...

Discussion on: Daily Challenge #9 - What's Your Number?

Collapse
choroba profile image
E. Choroba
#! /usr/bin/perl
use warnings;
use strict;

sub phone_num {
    local $" = "";
    "(@_[0 .. 2]) @_[3..5]-@_[6..9]"
}

use Test::More tests => 1;
is phone_num(0 .. 9), '(012) 345-6789';

The special variable $" is used to separate arrays interpolated in double quotes. By default, it contains a space, but we need the numbers to be adjacent, so we set it locally (i.e. in a dynamic scope) to an empty string.

Another possible short solution is

sub phone_num {
    "(012) 345-6789" =~ s/(\d)/$_[$1]/gr
}

The substitution replaces each digit in the template string with the corresponding element of the @_ array which keeps the list of the subroutine arguments. /g means "global", it's needed to replace all the digits, not just the first one. The /r means "return" - normally, a substitution changes the bound left-hand side value, but with /r, it just returns the value.

Collapse
yzhernand profile image
Yozen Hernandez

Nice, basically what I got. sprintf works as well.

#!/usr/bin/env perl

use strict;
use warnings;

sub createPhoneNumber {
    sprintf "(%s%s%s) %s%s%s-%s%s%s%s", @_;
    # local $" = "";
    # "(@_[0..2]) @_[3..5]-@_[6..9]";
}

print createPhoneNumber(1, 2, 3, 4, 5, 6, 7, 8, 9, 0) . "\n";

The regex solution was pretty interesting. Thanks for the explanation!